home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Technotools
/
Technotools (Chestnut CD-ROM)(1993).ISO
/
lantools
/
bkup
/
b_proces.bat
< prev
next >
Wrap
DOS Batch File
|
1990-08-23
|
3KB
|
73 lines
:... B_PROCES.BAT, Craig MacPherson
: This batch file processes backup requestes from users. It is called
: from the users backup job batch file. This file is processed on the
: backup server.
:
: Variables passed
: - %1 Userid
: - %2 Drive
: - %3 ALL or MOD file backup indicator
:... Del the que file to indicate processing has started
del %D2%\backups\backup.jbs\%1.que
:... Load Map Assist and connect to users workstation, remote drive o:
MA o:=Trilan1/%1
if errorlevel 1 goto NO_CONNECT
:... Clean out skipped and corrupt file logs
call %D1%b_skip.bat DELETE
:... Which backup to run Mod or Full
:ALL
set STATUS=GOOD
if not %3.==ALL. goto MODIFIED_FILES_ONLY
tbackup o:\/s/la:"%1 Complete backup - Drive %2"/a/li:"files.tmp":a
if errorlevel set STATUS=BAD
goto UPDATE_LOGS
:MODIFIED_FILES_ONLY
tbackup o:\/s/m/la:"%1 Modified files only Drive - %2"/a/li:"files.tmp":a
if errorlevel set STATUS=BAD
:UPDATE_LOGS
:USERS DETAILED LOG
:... Add current tape volume to users detailed history log
copy %D2%\backups\activity.lgs\%1.his+%D2%\backups\cur_tape.vol %D2%\backups\activity.lgs\%1.his
:... Add Maynard tape program output to users detailed history log
if not exist %D2%\backups\backup.jbs\files.tmp set STATUS=BAD
if not exist %D2%\backups\backup.jbs\files.tmp echo " Backup Failed">>%D2%\backups\activity.lgs\%1.his
copy %D2%\backups\activity.lgs\%1.his+%D2%\backups\backup.jbs\files.tmp %D2%\backups\activity.lgs\%1.his
if exist %D2%\backups\backup.jbs\files.tmp del %D2%\backups\backup.jbs\files.tmp>>nul:
:... Check for skipped or corrupt files, add info to users detailed history log
call %D1%b_skip.bat %1
goto MARK_EOJ
:NO_CONNECT
:... Mark users history log with no connect message
copy %D2%\backups\activity.lgs\%1.his+%D2%\backups\no_con.asc %D2%\backups\activity.lgs\%1.his
set STATUS=NO_CON
:MARK_EOJ
:... Mark EOJ in users history file
call %D1%b_eoj.bat %1
:... Strip Form Feeds from users history file
call %D1%b_strip.bat %1
:SYSTEM AND USER SUMMARY LOGS
:... Add user info and status to system activity log and user summary log
call %D1%b_activ.bat BACKUP %STATUS% %1 %2 %3
:... Unload Mapassist
MA -
:... Send user a message
send "Backup of Drive %2 Completed" %1
:END